Как в БП3.0 (БСП) получить структру адреса?

&НаСервереБезКонтекста
Процедура ЗначениеРеквизитовПоКонтактнойИнформации(Контекст, РедактируемаяИнформация)

    ДанныеАдреса = РедактируемаяИнформация.Состав;

    // Общие реквизиты
    Контекст.ПредставлениеАдреса = РедактируемаяИнформация.Представление;
    Контекст.Комментарий         = РедактируемаяИнформация.Комментарий;

    // Копия комментария для анализа измененности
    Контекст.КопияКомментария = Контекст.Комментарий;

    // Страна по наименованию
    НаименованиеСтраны = СокрЛП(ДанныеАдреса.Страна);
    Если ПустаяСтрока(НаименованиеСтраны) Тогда
        Контекст.Страна = Справочники.СтраныМира.ПустаяСсылка();
    Иначе
        СсылкаНаРоссию = Справочники.СтраныМира.Россия;
        Если ВРЕГ(НаименованиеСтраны)=ВРЕГ(СокрЛП(СсылкаНаРоссию.Наименование)) Тогда
            Контекст.Страна    = СсылкаНаРоссию;
            Контекст.КодСтраны = СсылкаНаРоссию.Код;
        Иначе
            ДанныеСтраны = Справочники.СтраныМира.ДанныеСтраныМира(, НаименованиеСтраны);
            Если ДанныеСтраны=Неопределено Тогда
                // Не нашли ни в справочнике, ни в классификаторе
                Контекст.Страна    = Неопределено;
                Контекст.КодСтраны = Неопределено;
            Иначе
                Контекст.Страна    = ДанныеСтраны.Ссылка;
                Контекст.КодСтраны = ДанныеСтраны.Код;
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;

    ВычисленноеПредставление = КонтактнаяИнформацияСлужебный.СформироватьПредставлениеКонтактнойИнформации(
        РедактируемаяИнформация, Контекст.ВидКонтактнойИнформации);

    Если КонтактнаяИнформацияСлужебный.ЭтоРоссийскийАдрес(ДанныеАдреса) Тогда
        Контекст.РазрешитьВводАдресаВСвободнойФорме = Не ПустаяСтрока(ДанныеАдреса.Состав.Адрес_по_документу);

        // Дополнительно проверяем случай, когда представление по документу равно вычисленному
        Если Контекст.РазрешитьВводАдресаВСвободнойФорме Тогда
            Если ПредставленияАдресаОдинаковы(ВычисленноеПредставление, ДанныеАдреса.Состав.Адрес_по_документу, Истина)
                И ПредставленияАдресаОдинаковы(РедактируемаяИнформация.Представление, ДанныеАдреса.Состав.Адрес_по_документу, Истина)
            Тогда
                Контекст.РазрешитьВводАдресаВСвободнойФорме = Ложь;
                ДанныеАдреса.Состав.Адрес_по_документу      = "";
            КонецЕсли;
        КонецЕсли;
    Иначе
        Контекст.ПредставлениеИностранногоАдреса = Строка(ДанныеАдреса.Состав);
    КонецЕсли;

    // Индекс просто ставим
    Контекст.Индекс = Формат(КонтактнаяИнформацияСлужебный.ПочтовыйИндексАдреса(ДанныеАдреса), "ЧГ=");

    // Синтетический "Населенный пункт" получаем как представление
    Контекст.НаселенныйПункт = КонтактнаяИнформацияСлужебный.ПредставлениеНаселенногоПункта(ДанныеАдреса);
    АнализКлассификатора = КонтактнаяИнформацияСлужебный.НаселенныеПунктыПоПредставлению(Контекст.НаселенныйПункт);
    Если АнализКлассификатора.ДанныеВыбора.Количество()=1 Тогда
        ВыбранноеЗначение = АнализКлассификатора.ДанныеВыбора[0].Значение.Значение;
        Контекст.КодКлассификатораНаселенногоПункта = ВыбранноеЗначение.Код;
        Контекст.НаселенныйПунктНайденТочно         = Истина;
        Контекст.НаселенныйПункт                    = ВыбранноеЗначение.Представление;
    Иначе
        Контекст.КодКлассификатораНаселенногоПункта = 0;
        Контекст.НаселенныйПунктНайденТочно         = Ложь;
        // Наименование населенного пункта не трогаем
    КонецЕсли;

    СформироватьДетальныйНаселенныйПункт(Контекст, ДанныеАдреса);

    // Синтетическую "Улицу" получаем как представление
    Контекст.Улица = КонтактнаяИнформацияСлужебный.ПредставлениеУлицы(ДанныеАдреса);
    АнализКлассификатора = КонтактнаяИнформацияСлужебный.УлицыПоПредставлению(Контекст.КодКлассификатораНаселенногоПункта, Контекст.Улица);
    Если АнализКлассификатора.ДанныеВыбора.Количество()=1 Тогда
        ВыбранноеЗначение = АнализКлассификатора.ДанныеВыбора[0].Значение.Значение;
        Контекст.КодКлассификатораУлицы = ВыбранноеЗначение.Код;
        Контекст.УлицаНайденаТочно      = Истина;
        Контекст.Улица                  = ВыбранноеЗначение.Представление;
    Иначе
        Контекст.КодКлассификатораУлицы = 0;
        Контекст.УлицаНайденаТочно      = Ложь;
        // Наименование улицы не трогаем
    КонецЕсли;

    // Дом, строение, помещение
    ЗданияИПомещения = КонтактнаяИнформацияСлужебный.ЗданияИПомещенияАдреса(ДанныеАдреса);

    // Первые два здания выделяем отдельно, остальное в списке
    ТаблицаДанных = ЗданияИПомещения.Здания;

    // Вид = 1 - признак дома, владения. Вид = 2, доп строение
    СтрокаДома = ТаблицаДанных.Найти(1, "Вид");
    Если СтрокаДома<>Неопределено Тогда
        Контекст.ТипДома = СтрокаДома.Тип;
        Контекст.Дом     = СтрокаДома.Значение;
        Контекст.ДомНайденТочно = Истина;
        ТаблицаДанных.Удалить(СтрокаДома);
    Иначе
        Контекст.ДомНайденТочно = Ложь;
    КонецЕсли;

    СтрокаДома = ТаблицаДанных.Найти(2, "Вид");
    Если СтрокаДома<>Неопределено Тогда
        Контекст.ТипСтроения = СтрокаДома.Тип;
        Контекст.Строение    = СтрокаДома.Значение;
        ТаблицаДанных.Удалить(СтрокаДома);
    КонецЕсли;

    НомерСтроки  = ТаблицаДанных.Количество();
    Пока НомерСтроки>0 Цикл
        НомерСтроки = НомерСтроки - 1;
        ЗаполнитьЗначенияСвойств(Контекст.ДополнительныеЗдания.Вставить(0), ТаблицаДанных[НомерСтроки]);
    КонецЦикла;

    // Первое помещение указываем отдельно, остальные в списке
    ТаблицаДанных = ЗданияИПомещения.Помещения;
    НомерСтроки   = ТаблицаДанных.Количество();
    Если НомерСтроки>0 Тогда
        Контекст.ТипПомещения = ТаблицаДанных[0].Тип;
        Контекст.Помещение    = ТаблицаДанных[0].Значение;
    КонецЕсли;
    Пока НомерСтроки>1 Цикл
        НомерСтроки = НомерСтроки - 1;
        ЗаполнитьЗначенияСвойств(Контекст.ДополнительныеПомещения.Вставить(0), ТаблицаДанных[НомерСтроки]);
    КонецЦикла;

    // Если переданное представление отличается от вычисленного, то адрес изменен
    Если Не Контекст.РазрешитьВводАдресаВСвободнойФорме И Не ПредставленияАдресаОдинаковы(Контекст.ПредставлениеАдреса, ВычисленноеПредставление) Тогда
        Контекст.Модифицированность = Истина;
    КонецЕсли;

КонецПроцедуры