Получение файлов ДО из БУХ

03.06.25

✎

11:17

Добрый день,

разбираюсь с интеграцией ДО с Бухгалтерией. Конкретно, надо получить информацию из справочника Файлы в обработке, т.е. программно на стороне БУХ.

Где вообще описаны доступные способы/примеры программно получить подобную информацию. Я не могу их найти. Что-то похожее есть в общих модулях на стороне Бух, но к ним же должна быть документация?

Версия БИД Версия 1.1.18, версия ДО 2 Корп

1 PLUT

гуру

03.06.25

✎

11:19

(0) почитайте для начала

Описание веб-сервисов.html
Описание механизмов интеграции.doc

в каталоге шаблонов 1С, что-то типа: ...tmplts\1c\DocMngCorpRuEng (не знаю, у вас обычный ДО или КОРП)

2 Bigbro

03.06.25

✎

11:27

смотрите в конфигурации про DMService и в частности DMGetObjectListRequest

3 rozer76

03.06.25

✎

12:42

если нет в штатной интеграции то примерно так:
в ДО http-сервис по ИНН, ну в БУХ можно даже файл открыть, если он хранится в "томах".

Подробности

Функция ПолучитьФайлыGET(Запрос)

    Попытка
        Ответ = Новый HTTPСервисОтвет(200);
        ИНН = Запрос.ПараметрыURL["inn"];
        СтрокаJSON = ПолучитьФайлыПоИНН(ИНН);
        Ответ.УстановитьТелоИзСтроки(СтрокаJSON,КодировкаТекста.UTF8,ИспользованиеByteOrderMark.Использовать);
    Исключение
        Ответ = Новый HTTPСервисОтвет(404);
        ТекстСообщения = СтрШаблон(НСтр("ru = 'Ошибка метода ПолучитьФайлыGET %1'"), ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
        Ответ.УстановитьТелоИзСтроки(ТекстСообщения);
    КонецПопытки;

    Возврат Ответ;

КонецФункции

Функция ПолучитьФайлыПоИНН(ИНН)

    Если НЕ ЗначениеЗаполнено(ИНН) Тогда
        ВызватьИсключение "Не указан ИНН";
    КонецЕсли;

    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("ИНН", ИНН);
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ВнутренниеДокументы.Ссылка КАК Ссылка,
    |    ВнутренниеДокументы.Контрагент КАК Контрагент,
    |    ВнутренниеДокументы.Наименование КАК Наименование
    |ПОМЕСТИТЬ втВладелецФайлов
    |ИЗ
    |    Справочник.ВнутренниеДокументы КАК ВнутренниеДокументы
    |ГДЕ
    |    ВнутренниеДокументы.Контрагент.ИНН = &ИНН
    |    И НЕ ВнутренниеДокументы.ПометкаУдаления
    |    И ВнутренниеДокументы.Контрагент <> ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    втВладелецФайлов.Наименование КАК ВладелецНаименование,
    |    Файлы.ТекущаяВерсияРасширение КАК Расширение,
    |    Файлы.ТекущаяВерсияПутьКФайлу КАК ПутьКФайлуВТоме,
    |    ЕСТЬNULL(Файлы.ТекущаяВерсияТом.ПолныйПутьWindows, """") КАК ПутьКТому,
    |    втВладелецФайлов.Ссылка КАК ВладелецСсылка,
    |    Файлы.Наименование КАК НаименованиеФайла,
    |    Файлы.ДатаСоздания КАК ДатаСозданияФайла
    |ИЗ
    |    втВладелецФайлов КАК втВладелецФайлов
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Файлы КАК Файлы
    |        ПО втВладелецФайлов.Ссылка = Файлы.ВладелецФайла
    |            И (НЕ Файлы.ПометкаУдаления)
    |            И (НЕ Файлы.Зашифрован)
    |            И (Файлы.ТекущаяВерсияТом <> ЗНАЧЕНИЕ(Справочник.ТомаХраненияФайлов.ПустаяСсылка))
    |
    |УПОРЯДОЧИТЬ ПО
    |    ВладелецНаименование";

    УстановитьПривилегированныйРежим(Истина);
    Результат = Запрос.Выполнить();
    Выборка = Результат.Выбрать();
    Массив = Новый Массив;
    Пока Выборка.Следующий()Цикл
        Если ЗначениеЗаполнено(Выборка.ПутьКТому)
            И ЗначениеЗаполнено(Выборка.ПутьКФайлуВТоме) Тогда
            ПутьКФайлу = Выборка.ПутьКТому + Выборка.ПутьКФайлуВТоме;
            СрокДействияСтрока = ДелопроизводствоКлиентСервер.СформироватьПредставлениеСрокаДействия(Выборка.ВладелецСсылка);
            СрокДействияСтрока = СтрЗаменить(СрокДействияСтрока,Символы.ПС," ");
            ПредставлениеВладельца = СтрШаблон(НСтр("ru = '%1 (%2)'"), Выборка.ВладелецНаименование, Выборка.НаименованиеФайла);
            Структура = Новый Структура("Владелец, Расширение, ПутьКФайлу, СрокДействия, ДатаСозданияФайла",
            ПредставлениеВладельца, Выборка.Расширение, ПутьКФайлу, СрокДействияСтрока, Выборка.ДатаСозданияФайла);
            ЗаполнитьЗначенияСвойств(Структура, Выборка);
            Массив.Добавить(Структура);
        КонецЕсли;
    КонецЦикла;
    УстановитьПривилегированныйРежим(Ложь);

    НастройкиСериализацииJSON = Новый НастройкиСериализацииJSON;
    НастройкиСериализацииJSON.ВариантЗаписиДаты         = ВариантЗаписиДатыJSON.ЛокальнаяДата;
    НастройкиСериализацииJSON.ФорматСериализацииДаты     = ФорматДатыJSON.ISO;

    Возврат СериализоватьJSON(Массив,НастройкиСериализацииJSON);

КонецФункции

4 Terrixus

03.06.25

✎

15:20

(2) получаю объекты типа DMFile, почему-то слишком мало полей. Например, нет даже расширения, владельца, даты создания... Что я делаю не так? Я могу как-то отфильтровать их по имени владельцу, например?

Вот код

    Прокси = ИнтеграцияС1СДокументооборотПовтИсп.ПолучитьПрокси();
    Запрос = ИнтеграцияС1СДокументооборот.СоздатьОбъект(Прокси, "DMGetObjectListRequest");
    Запрос.type = "DMFile";
    //Запрос.query = СписокУсловий;

    Результат = Прокси.execute(Запрос);
    ИнтеграцияС1СДокументооборот.ПроверитьВозвратВебСервиса(Прокси, Результат);

    Для Каждого Элемент из Результат.items Цикл
        Сообщить(СтрШаблон("%1 %2 %3", Элемент.object.name,  Элемент.object.objectId.id, Элемент.object.objectId.type ));
    КонецЦикла;

5 Garykom

гуру

03.06.25

✎

15:31

(4) columnSet установи для возврата
или для каждого в цикле запрашивай конкретный DMFile

6 Garykom

гуру

03.06.25

✎

15:32

(4) для фильтра в ДО изучи в конфигураторе ОбработкаЗапросовXDTO.ОбработатьУниверсальноеСообщение
ищи подходящий

7 Garykom

гуру

03.06.25

✎

15:33

(6)+ например

ИначеЕсли ПроверитьТип(Сообщение, "DMGetFileListByOwnerRequest") Тогда
				Результат = ПолучитьСписокФайловПоВладельцу(Сообщение);

8 Garykom

гуру

03.06.25

✎