Я написал обработку на управляемых формах, которая создает документ. Требуется после создания документа, открыть его.

ну а в чем проблема? По ссылке получи форму и открой

Документ создается на сервере, появляется ошибка - Интерактивные действие невозможны.

Как на клиенте получить ссылку на документ ?

ДокументСсылка.<Имя документа> (DocumentRef.<Имя документа>)
Доступность:

Тонкий клиент, веб-клиент, сервер, толстый клиент, внешнее соединение.
передай ссылку на клиент, получи по ней форму и открой

Например так:

&НаКлиенте
Процедура СоздатьИОткрытьДокумент()
    
    РезультатСсылка = СоздатьМойДокумент();
    
    Если РезультатСсылка <> Неопределено Тогда
        П = Новый Структура("Ключ", РезультатСсылка);
        ФормаДок = ПолучитьФорму("Документ.МойДокумент.ФормаОбъекта", П);
        ФормаДок.Открыть();
    КонецЕсли;
    
КонецПроцедуры

&НаСервереБезКонтекста
Функция СоздатьМойДокумент()
    
    ДокументОбъект = Документы.МойДокумент.СоздатьДокумент();
    //Заполнение реквизитов документа...
    
    Попытка
        ДокументОбъект.Записать();
    Исключение
        Сообщение = Новый СообщениеПользователю;
        Сообщение.Текст = "Не удалось записать документ " + ОписаниеОшибки();
        Сообщение.Сообщить();
        
        Возврат Неопределено;
    КонецПопытки;
    
    Возврат ДокументОбъект.Ссылка;
    
КонецФункции

Спасибо! Идеально подошло.(5)