Не отображается результат запроса на СКД

1С v8

31.08.15

✎

09:55

Создаю внешний отчет на 8.2, в схеме компоновки данных добавляю запрос:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ЦеныНоменклатурыСрезПоследних.Период,
    ЦеныНоменклатурыСрезПоследних.Номенклатура,
    ЦеныНоменклатурыСрезПоследних.Цена,
    ЦеныНоменклатурыСрезПоследних.ТипЦен,
    ЦеныНоменклатурыСрезПоследних.Регистратор
ПОМЕСТИТЬ СтарыеЦены
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних({&Период}, ) КАК ЦеныНоменклатурыСрезПоследних

СГРУППИРОВАТЬ ПО
    ЦеныНоменклатурыСрезПоследних.Период,
    ЦеныНоменклатурыСрезПоследних.Номенклатура,
    ЦеныНоменклатурыСрезПоследних.Цена,
    ЦеныНоменклатурыСрезПоследних.ТипЦен,
    ЦеныНоменклатурыСрезПоследних.Регистратор
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    СтарыеЦены.Период КАК ПредыдущаяДата,
    ЦеныНоменклатурыСрезПоследних.Период КАК ТекущаяДата,
    ЦеныНоменклатурыСрезПоследних.Номенклатура,
    ЦеныНоменклатурыСрезПоследних.ТипЦен,
    СтарыеЦены.Цена КАК ПредыдущаяЦена,
    ЦеныНоменклатурыСрезПоследних.Цена КАК ТекущаяЦена
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ) КАК ЦеныНоменклатурыСрезПоследних
        ЛЕВОЕ СОЕДИНЕНИЕ СтарыеЦены КАК СтарыеЦены
        ПО ЦеныНоменклатурыСрезПоследних.Номенклатура = СтарыеЦены.Номенклатура
            И ЦеныНоменклатурыСрезПоследних.ТипЦен = СтарыеЦены.ТипЦен
ГДЕ
    ЦеныНоменклатурыСрезПоследних.Цена <> СтарыеЦены.Цена

СГРУППИРОВАТЬ ПО
    ЦеныНоменклатурыСрезПоследних.Период,
    ЦеныНоменклатурыСрезПоследних.Номенклатура,
    ЦеныНоменклатурыСрезПоследних.Цена,
    ЦеныНоменклатурыСрезПоследних.ТипЦен,
    СтарыеЦены.Цена,
    СтарыеЦены.Период

Консоль запросов возвращает значения, но отчет показывает только заголовки таблицы, и больше ничего. В чем может быть проблема?

1 Cube

31.08.15

✎

09:57

С параметрами виртуальных таблиц на закладке "Компоновка данных" в запросе намудрил 146%

2 varvest

31.08.15

✎

10:05

пробовал различные варианты, с обрамлением параметра в {}, и без. Какие могут быть еще варианты?

3 Timon1405

31.08.15

✎

10:07

берешь консоль СКД с ИТС, смотришь на итоговый запрос, который она возвращает, делаешь выводы

4 Cube

31.08.15

✎

10:46

(2) Телепатов нет. В приведенном куске в первом пакете параметр указан, а во втором нет... Компоновка 100% подставит сама параметр &Период во второй запрос, а ты, я так понимаю, этого не ожидаешь...

5 varvest

31.08.15

✎

10:47

Примерно в этом и было дело,  а также а методе указания параметра. Сработал этот вариант

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ПредыдущиеЦены.Период,
    ПредыдущиеЦены.Номенклатура,
    ПредыдущиеЦены.Цена,
    ПредыдущиеЦены.ТипЦен,
    ПредыдущиеЦены.Регистратор
ПОМЕСТИТЬ СтарыеЦены
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних({(&Период)}, ) КАК ПредыдущиеЦены

СГРУППИРОВАТЬ ПО
    ПредыдущиеЦены.Период,
    ПредыдущиеЦены.Номенклатура,
    ПредыдущиеЦены.Цена,
    ПредыдущиеЦены.ТипЦен,
    ПредыдущиеЦены.Регистратор
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    СтарыеЦены.Период КАК ПредыдущаяДата,
    ТекущиеЦены.Период КАК ТекущаяДата,
    ТекущиеЦены.Номенклатура,
    ТекущиеЦены.ТипЦен,
    СтарыеЦены.Цена КАК ПредыдущаяЦена,
    ТекущиеЦены.Цена КАК ТекущаяЦена
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних({(&ТекПериод)}, ) КАК ТекущиеЦены
        ЛЕВОЕ СОЕДИНЕНИЕ СтарыеЦены КАК СтарыеЦены
        ПО ТекущиеЦены.Номенклатура = СтарыеЦены.Номенклатура
            И ТекущиеЦены.ТипЦен = СтарыеЦены.ТипЦен
ГДЕ
    СтарыеЦены.Цена <> ТекущиеЦены.Цена

СГРУППИРОВАТЬ ПО
    ТекущиеЦены.Период,
    ТекущиеЦены.Номенклатура,
    ТекущиеЦены.Цена,
    ТекущиеЦены.ТипЦен,
    СтарыеЦены.Цена,
    СтарыеЦены.Период