Создание внешней печатной формы в ЗУП.

Сделала внешнюю печ. форму для командировочных, не заполняются реквизиты шапки. Их заполняю при помощи функции. Можно ли вызывать функции во внешней печ. форме?

Перем мДлинаСуток;

Функция СформироватьЗапросДляПечати(Режим)

    Запрос = Новый Запрос;

    // Установим параметры запроса
    Запрос.УстановитьПараметр("ДокументСсылка",    СсылкаНаОбъект.Ссылка);
    Запрос.УстановитьПараметр("ДатаДокумента",    СсылкаНаОбъект.Дата);

    Если Режим = "ПоРеквизитамДокумента" Тогда

        Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
        Запрос.УстановитьПараметр("СтруктурнаяЕдиница",СсылкаНаОбъект.Организация);

        Запрос.Текст = ФормированиеПечатныхФормЗК.ПолучитьТекстЗапросаПоОтветственнымЛицам(
            "ДатаДокумента",
            "ОтветственноеЛицо = ЗНАЧЕНИЕ(Перечисление.ОтветственныеЛицаОрганизаций.Руководитель)
            |И СтруктурнаяЕдиница = &СтруктурнаяЕдиница");
        Запрос.Выполнить();

        Запрос.Текст =
        "ВЫБРАТЬ
        |    КомандировкиОрганизаций.Дата КАК ДатаДок,
        |    КомандировкиОрганизаций.Номер КАК НомерДок,
        |    КомандировкиОрганизаций.Организация.НаименованиеПолное КАК НазваниеОрганизации,
        |    КомандировкиОрганизаций.Организация.КодПоОКПО КАК КодПоОКПО,
        |    КомандировкиОрганизаций.СтранаНазначения,
        |    КомандировкиОрганизаций.ОрганизацияНазначения,
        |    КомандировкиОрганизаций.ОснованиеКомандировки,
        |    ОтветственныеЛицаОрганизаций.Должность КАК ДолжностьРуководителя,
        |    ОтветственныеЛицаОрганизаций.НаименованиеОтветственногоЛица КАК ФИОРуководителя
        |ИЗ
        |    Документ.КомандировкиОрганизаций КАК КомандировкиОрганизаций
        |        ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеОбОтветственномЛице КАК ОтветственныеЛицаОрганизаций
        |        ПО (ИСТИНА)
        |ГДЕ
        |    КомандировкиОрганизаций.Ссылка = &ДокументСсылка";

    ИначеЕсли Режим = "ПоТабличнойЧастиДокумента" Тогда

        Запрос.УстановитьПараметр("Организация",     СсылкаНаОбъект.Организация);
        Запрос.УстановитьПараметр("ГоловнаяОрганизация", ОбщегоНазначенияЗК.ГоловнаяОрганизация(СсылкаНаОбъект.Организация));

        Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
        Запрос.Текст =
        "ВЫБРАТЬ
        |    КомандировкиОрганизацииРаботники.НомерСтроки,
        |    КомандировкиОрганизацииРаботники.Сотрудник.Физлицо КАК Физлицо,
        |    КомандировкиОрганизацииРаботники.Сотрудник КАК Сотрудник,
        |    КомандировкиОрганизацииРаботники.ФизЛицо.Пол КАК ФизЛицоПол,
        |    КомандировкиОрганизацииРаботники.ДатаНачала,
        |    КомандировкиОрганизацииРаботники.ДатаОкончания,
        |    КомандировкиОрганизацииРаботники.ОсвобождатьСтавку,
        |    КомандировкиОрганизацииРаботники.Цель,
        |    КомандировкиОрганизацииРаботники.ИсточникФинансирования,
        |    КомандировкиОрганизацииРаботники.НапомнитьПоЗавершении,
        |    КомандировкиОрганизацииРаботники.ВремяНахожденияВПути,
        |    КомандировкиОрганизацииРаботники.Сотрудник.Код КАК ТабельныйНомер
        |ПОМЕСТИТЬ ВТСотрудники
        |ИЗ
        |    Документ.КомандировкиОрганизаций.РаботникиОрганизации КАК КомандировкиОрганизацииРаботники
        |ГДЕ
        |    КомандировкиОрганизацииРаботники.Ссылка = &ДокументСсылка
        |    И (НЕ КомандировкиОрганизацииРаботники.Сторно)
        |
        |ИНДЕКСИРОВАТЬ ПО
        |    Сотрудник";
        Запрос.Выполнить();

        Запрос.Текст =
        "ВЫБРАТЬ
        |    ЕСТЬNULL(ФИОФизЛиц.Фамилия + "" "" + ФИОФизЛиц.Имя + "" "" + ФИОФизЛиц.Отчество, КомандировкиОрганизацииРаботники.Сотрудник.Наименование) КАК Работник,
        |    ЕСТЬNULL(ПаспортныеДанныеФизЛицСрезПоследних.ДокументВид.Наименование + "", серия "" + ПаспортныеДанныеФизЛицСрезПоследних.ДокументСерия + "", №"" + ПаспортныеДанныеФизЛицСрезПоследних.ДокументНомер, """") КАК РеквизитыПаспорта,
        |    КомандировкиОрганизацииРаботники.НомерСтроки КАК НомерСтроки,
        |    КомандировкиОрганизацииРаботники.ФизЛицоПол,
        |    КомандировкиОрганизацииРаботники.ДатаНачала,
        |    КомандировкиОрганизацииРаботники.ДатаОкончания,
        |    КомандировкиОрганизацииРаботники.ВремяНахожденияВПути,
        |    КомандировкиОрганизацииРаботники.Цель,
        |    ВЫБОР
        |        КОГДА Работники.ПериодЗавершения <= КомандировкиОрганизацииРаботники.ДатаНачала
        |                И Работники.ПериодЗавершения <> ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)
        |            ТОГДА Работники.ПодразделениеОрганизацииЗавершения
        |        ИНАЧЕ Работники.ПодразделениеОрганизации
        |    КОНЕЦ КАК ПодразделениеРаботника,
        |    ВЫБОР
        |        КОГДА Работники.ПериодЗавершения <= КомандировкиОрганизацииРаботники.ДатаНачала
        |                И Работники.ПериодЗавершения <> ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)
        |            ТОГДА Работники.ДолжностьЗавершения
        |        ИНАЧЕ Работники.Должность
        |    КОНЕЦ КАК Должность,
        |    КомандировкиОрганизацииРаботники.ИсточникФинансирования,
        |    КомандировкиОрганизацииРаботники.ТабельныйНомер
        |ИЗ
        |    ВТСотрудники КАК КомандировкиОрганизацииРаботники
        |        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
        |            СписокДат.Сотрудник КАК Сотрудник,
        |            Работники.ПодразделениеОрганизации.Наименование КАК ПодразделениеОрганизации,
        |            Работники.Должность.Наименование КАК Должность,
        |            Работники.ПодразделениеОрганизацииЗавершения.Наименование КАК ПодразделениеОрганизацииЗавершения,
        |            Работники.ДолжностьЗавершения.Наименование КАК ДолжностьЗавершения,
        |            Работники.ПериодЗавершения КАК ПериодЗавершения
        |        ИЗ
        |            (ВЫБРАТЬ
        |                РаботникиВнутри.Сотрудник КАК Сотрудник,
        |                МАКСИМУМ(РаботникиВнутри.Период) КАК ДатаПоследнегоИзменения
        |            ИЗ
        |                РегистрСведений.РаботникиОрганизаций КАК РаботникиВнутри
        |                    ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТСотрудники КАК КомандировкиОрганизаций
        |                    ПО РаботникиВнутри.Период <= КомандировкиОрганизаций.ДатаНачала
        |                        И РаботникиВнутри.Сотрудник = КомандировкиОрганизаций.Сотрудник
        |
        |            СГРУППИРОВАТЬ ПО
        |                РаботникиВнутри.Сотрудник) КАК СписокДат
        |                ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций КАК Работники
        |                ПО СписокДат.ДатаПоследнегоИзменения = Работники.Период
        |                    И СписокДат.Сотрудник = Работники.Сотрудник) КАК Работники
        |        ПО КомандировкиОрганизацииРаботники.Сотрудник = Работники.Сотрудник
        |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ФИОФизЛиц.СрезПоследних(
        |                &ДатаДокумента,
        |                ФизЛицо В
        |                    (ВЫБРАТЬ
        |                        Сотрудники.Физлицо
        |                    ИЗ
        |                        ВТСотрудники КАК Сотрудники)) КАК ФИОФизЛиц
        |        ПО КомандировкиОрганизацииРаботники.Сотрудник.Физлицо = ФИОФизЛиц.ФизЛицо
        |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ПаспортныеДанныеФизЛиц.СрезПоследних(
        |                &ДатаДокумента,
        |                ФизЛицо В
        |                    (ВЫБРАТЬ
        |                        Сотрудники.Физлицо
        |                    ИЗ
        |                        ВТСотрудники КАК Сотрудники)) КАК ПаспортныеДанныеФизЛицСрезПоследних
        |        ПО КомандировкиОрганизацииРаботники.Сотрудник.Физлицо = ПаспортныеДанныеФизЛицСрезПоследних.ФизЛицо
        |
        |УПОРЯДОЧИТЬ ПО
        |    НомерСтроки";

    Иначе
        Возврат Неопределено;

    КонецЕсли;

    Возврат Запрос.Выполнить();

КонецФункции // СформироватьЗапросДляПечати()

Функция Печать() Экспорт
    ТабДокумент = Новый ТабличныйДокумент;
    ТабДокумент.ИмяПараметровПечати    = "ПАРАМЕТРЫ_ПЕЧАТИ_КомандировкиОрганизации_Т9";
    ТабДокумент.ОриентацияСтраницы    = ОриентацияСтраницы.Портрет;

    // получаем данные для печати
    ВыборкаДляШапки        = СформироватьЗапросДляПечати("ПоРеквизитамДокумента").Выбрать();
    //  Т=  СформироватьЗапросДляПечати("ПоРеквизитамДокумента").Выгрузить();
     // Т.ВыбратьСтроку();
      ВыборкаРаботники    = СформироватьЗапросДляПечати("ПоТабличнойЧастиДокумента").Выбрать();

    // запоминаем области макета
    Макет = ПолучитьМакет("Макет");
    ОбластьМакетаШапка    = Макет.ПолучитьОбласть("Шапка"); // Шапка документа
    ОбластьМакетаПодвал    = Макет.ПолучитьОбласть("Подвал"); // Подвал документа
    ОбластьМакета        = Макет.ПолучитьОбласть("Работник"); // строка работника

    // выводим данные о руководителях организации
    Если ВыборкаДляШапки.Следующий() Тогда
        ОбластьМакетаШапка.Параметры.Заполнить(ВыборкаДляШапки); // Шапка документа.
        ОбластьМакетаШапка.Параметры.НазваниеОрганизации    = СокрЛП(ОбластьМакетаШапка.Параметры.НазваниеОрганизации);
        ОбластьМакетаПодвал.Параметры.Заполнить(ВыборкаДляШапки); // Для подвала.
        ОбластьМакета.Параметры.Заполнить(ВыборкаДляШапки); // область работника
        ВыводитьДатуОзнакомленияСПриказом = ПроцедурыУправленияПерсоналом.ЗначениеУчетнойПолитикиПоПерсоналуОрганизации(глЗначениеПеременной("глУчетнаяПолитикаПоПерсоналуОрганизации"), СсылкаНаОбъект.Организация, "ПроставлятьАвтоматическиДатуОзнакомленияВКадровыхПриказах");
        Если Не ВыводитьДатуОзнакомленияСПриказом Тогда
            ОбластьМакетаПодвал.Параметры.ДатаДок = ФормированиеПечатныхФормЗК.ПустаяДатаВПечатнойФорме();
        КонецЕсли;
        НомерДокДляПечати    = ВыборкаДляШапки.НомерДок;
    КонецЕсли;

    НомерФормы = 0;
    ПечататьПостфикс = ВыборкаРаботники.Количество() > 1;

    // Начинаем формировать выходной документ
    Пока ВыборкаРаботники.Следующий() Цикл

        // Каждый приказ на отдельной странице.
        Если ТабДокумент.ВысотаТаблицы > 0 Тогда
            ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц();
        КонецЕсли;

        // Шапка документа.
        Если ПечататьПостфикс Тогда
            НомерФормы = НомерФормы + 1;
            ОбластьМакетаШапка.Параметры.НомерДок = НомерДокДляПечати + "/" + НомерФормы
        КонецЕсли;
        ТабДокумент.Вывести(ОбластьМакетаШапка);

        // Данные по работнику.
        ОбластьМакета.Параметры.Заполнить(ВыборкаРаботники);

        РезультатСклонения = "";
        Если УниверсальныеМеханизмы.Просклонять(глЗначениеПеременной("глКомпонентаСклоненияФИО"), ВыборкаРаботники.Работник, 4,ВыборкаРаботники.ФизЛицоПол, РезультатСклонения) Тогда
            ОбластьМакета.Параметры.Работник    = РезультатСклонения
        КонецЕсли;

        //уберем из табельного номера префикс
        ОбластьМакета.Параметры.ТабельныйНомер = ВыборкаРаботники.ТабельныйНомер;

        ОбластьМакета.Параметры.Продолжительность = ?(ЗначениеЗаполнено(ВыборкаРаботники.ДатаОкончания),Цел((ВыборкаРаботники.ДатаОкончания - ВыборкаРаботники.ДатаНачала + 1) / мДлинаСуток) + 1,"");
        ТабДокумент.Вывести(ОбластьМакета);

        Если Не ВыводитьДатуОзнакомленияСПриказом Тогда
            ОбластьМакетаПодвал.Параметры.ДатаДок = ФормированиеПечатныхФормЗК.ПустаяДатаВПечатнойФорме();
        КонецЕсли;

        // Подвал документа.
        ТабДокумент.Вывести(ОбластьМакетаПодвал);

    КонецЦикла;

    // если не было ни одного работника - выводим пустой бланк
    Если ТабДокумент.ВысотаТаблицы = 0 Тогда
        ТабДокумент.Вывести(ОбластьМакетаШапка);
        ТабДокумент.Вывести(ОбластьМакета);
        ТабДокумент.Вывести(ОбластьМакетаПодвал);
    КонецЕсли;

    Возврат ТабДокумент;


Конецфункции

мДлинаСуток = 86400;

выходит пустой документ.