Есть запрос для данных на конец периода

ВЫБРАТЬ
Движения.Номенклатура,
ДНИ.Период,
СУММА(ВЫБОР
КОГДА Движения.Период = &НачалоПериода
ТОГДА Движения.КоличествоКонечныйОстаток
ИНАЧЕ ВЫБОР
КОГДА Движения.Период < = ДНИ.Период
ТОГДА Движения.КоличествоОборот
ИНАЧЕ 0
КОНЕЦ
КОНЕЦ) КАК КоличествоКонечныйОстаток
ИЗ
Дни КАК ДНИ,
РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , Номенклатура = &Номенклатура) КАК Движения

СГРУППИРОВАТЬ ПО
Движения.Номенклатура,
ДНИ.Период


Не могу переделать для начальных остатков ... ((


ВЫБОР
        КОГДА ОстаткиПоМесяцам.ПериодМесяц = &НачалоПериода
            ТОГДА ОстаткиПоМесяцам.НачальныйОстатокПоМесяцам
        КОГДА ПериодыМ.ПериодМесяц > ДОБАВИТЬКДАТЕ(ОстаткиПоМесяцам.ПериодМесяц, секунда, 1)
                ТОГДА ОстаткиПоМесяцам.КоличествоОборотПоМесяцам * -1
    
            ИНАЧЕ 0
    КОНЕЦ КАК Остаток,

В случае, когда берем 3 месяца, есть начальный остаток только на дату начала - запрос попадает на первое условие всегда и соответственно выводит показатели 1го месяца для каждого последуйщего (

Что за изврат? Группировка Месяц и стандартные НачальныйОстаток и КонечныйОстаток чем не устраивают?

>ВЫБОР
КОГДА Движения.Период = &НачалоПериода
ТОГДА Движения.КоличествоКонечныйОстаток

напоминает баян:

true = false
false = true

//счастливой отладки с.ки!

(1) - попробуй сделать и очень сильно удивишься результату, когда не было движений в периоде )

(3) Как раз наоборот для конечного остатка логично, получении кон кол на начало, затем построчный вывод оборота, при группировке все ровняется как надо.

то есть (2)*

Никто не сталкивался что ли???

Если кому пригодится решение найдено:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    НАЧАЛОПЕРИОДА(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря, МЕСЯЦ) КАК ПериодМесяц
ПОМЕСТИТЬ ПериодыМ
ИЗ
    РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря МЕЖДУ &НачалоПериода И &КонецПериода

СГРУППИРОВАТЬ ПО
    НАЧАЛОПЕРИОДА(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря, МЕСЯЦ)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ТоварыНаСкладахОстаткиИОбороты.Период КАК ПериодМесяц,
    ТоварыНаСкладахОстаткиИОбороты.Номенклатура,
    ТоварыНаСкладахОстаткиИОбороты.ХарактеристикаНоменклатуры,
    ТоварыНаСкладахОстаткиИОбороты.КоличествоНачальныйОстаток КАК НачальныйОстатокПоМесяцам,
    ТоварыНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток КАК КонечныйОстатокПоМесяцам
ПОМЕСТИТЬ ОстаткиПоМесяцам
ИЗ
    РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(
            &НачалоПериода,
            &КонецПериода,
            Месяц,
            ,
            Номенклатура В (&Номенклатура)
                И склад В (&СкладОстаткиПоМесяцам)) КАК ТоварыНаСкладахОстаткиИОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ОпределениеПериода.ПериодМесяц,
    ОпределениеПериода.Номенклатура,
    ОпределениеПериода.ХарактеристикаНоменклатуры,
    ОпределениеПериода.ПериодМесяцДляСвязи,
    ВЫБОР
        КОГДА ОпределениеПериода.ПериодМесяц = ОпределениеПериода.ПериодМесяцДляСвязи
            ТОГДА ОстаткиПоМесяцам.НачальныйОстатокПоМесяцам
        ИНАЧЕ ОстаткиПоМесяцам.КонечныйОстатокПоМесяцам
    КОНЕЦ КАК Остаток
ИЗ
    (ВЫБРАТЬ
        ПериодыМ.ПериодМесяц КАК ПериодМесяц,
        ОстаткиПоМесяцам.Номенклатура КАК Номенклатура,
        ОстаткиПоМесяцам.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
        МАКСИМУМ(ОстаткиПоМесяцамПериоды.ПериодМесяц) КАК ПериодМесяцДляСвязи
    ИЗ
        ПериодыМ КАК ПериодыМ
            ЛЕВОЕ СОЕДИНЕНИЕ ОстаткиПоМесяцам КАК ОстаткиПоМесяцамПериоды
                ЛЕВОЕ СОЕДИНЕНИЕ ОстаткиПоМесяцам КАК ОстаткиПоМесяцам
                ПО ОстаткиПоМесяцамПериоды.Номенклатура = ОстаткиПоМесяцам.Номенклатура
                    И ОстаткиПоМесяцамПериоды.ХарактеристикаНоменклатуры = ОстаткиПоМесяцам.ХарактеристикаНоменклатуры
            ПО ПериодыМ.ПериодМесяц >= ОстаткиПоМесяцамПериоды.ПериодМесяц
    
    СГРУППИРОВАТЬ ПО
        ПериодыМ.ПериодМесяц,
        ОстаткиПоМесяцам.Номенклатура,
        ОстаткиПоМесяцам.ХарактеристикаНоменклатуры) КАК ОпределениеПериода
        ЛЕВОЕ СОЕДИНЕНИЕ ОстаткиПоМесяцам КАК ОстаткиПоМесяцам
        ПО ОпределениеПериода.Номенклатура = ОстаткиПоМесяцам.Номенклатура
            И ОпределениеПериода.ХарактеристикаНоменклатуры = ОстаткиПоМесяцам.ХарактеристикаНоменклатуры
            И ОпределениеПериода.ПериодМесяцДляСвязи = ОстаткиПоМесяцам.ПериодМесяц