Всем привет! Никак не получается организовать отбор по списку значений в построителе запроса.
    
ПостроительЗапроса.Текст =
        "ВЫБРАТЬ
        |    ОтчетКомитентуОПродажах.Ссылка КАК Документ,
        |    ОтчетКомитентуОПродажах.Контрагент КАК Контрагент,
        |    КонтрагентыКонтактнаяИнформация.Представление КАК СписокЭлектронныхАдресов
        |ИЗ
        |    Документ.ОтчетКомитентуОПродажах КАК ОтчетКомитентуОПродажах
        |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформация
        |        ПО ОтчетКомитентуОПродажах.Контрагент = КонтрагентыКонтактнаяИнформация.Ссылка
        |            И (КонтрагентыКонтактнаяИнформация.Тип = &ТипКонтактнойИнформации)
        |            И (КонтрагентыКонтактнаяИнформация.Вид = &ВидКонтактнойИнформации)
        |ГДЕ
        |    ОтчетКомитентуОПродажах.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |{ГДЕ
        |    ОтчетКомитентуОПродажах.Контрагент.*}";
    
    Если ЗначениеЗаполнено(Объект.Контрагент) Тогда
        ОтборПоКонтрагенту = ПостроительЗапроса.Отбор.Добавить("Контрагент");
        ОтборПоКонтрагенту.Значение = Объект.Контрагент;
        ОтборПоКонтрагенту.ВидСравнения = ВидСравнения.ВСписке;
        ОтборПоКонтрагенту.Использование = Истина;
    КонецЕсли;

Ругается на неверный тип в отборе. Как это сделать?

Да, "Контрагент" - Это реквизит обработки с типом "СписокЗначений"

ОтборПоКонтрагенту.Значение = Объект.Контрагент.ВыгрузитьЗначения();

(2) Так тоже ругается на тип значения. Он ждет Тип значения "КонтрагентСсылка", а я не пойму как ему список пихнуть

Если передать конкретного контрагента, то все отрабатывает правильно

Местами попробуй поменять строчки с ВидСравнения и Значение
(вроде был такой прикол)

(5) Бл..ть, так работает. Огромное мерси!

"ОтборПоКонтрагенту.Значение = Объект.Контрагент;
ОтборПоКонтрагенту.ВидСравнения = ВидСравнения.ВСписке;
"

Абрам Моисеевич, Вы или трусики наденьте, или крестик снимите...

В смысле - если указываешь "в списке", Так и передеавай список...

(7) Так и передаю, там прикол в порядке строк в коде

(6) По умолчанию ВидСравнения  -  это ВидСравнения.Равно, поэтому когда туда передается список он преобразуется к единичному значению и когда потом устанавливается ВидСравнения.ВСписке происходит такая ошибка. Поэтому всегда надо сначала ВидСравнения устнавливать, а потом Значение.
Это не только в построителе запроса, это вообще везде, где используется Отбор.