Подскажите пожалуйста, можно ли через расширение отключить регистрацию объектов в плане обмена?
Добавить новые получается, а вот существующие в конфигурации нет :(

Спасибо

(0) так их в правилах регистрации можно отключить же

(0)
можно и кодом, я так отключил регистрацию в БП, чтобы физлица из БП не ехали в ЗУП.

&Вместо("СинхронизацияДанныхЧерезУниверсальныйФорматПередЗаписью")
Процедура Откл_СинхронизацияДанныхЧерезУниверсальныйФорматПередЗаписью(Источник, Отказ)
    Если Откл_ПропуститьРегистрациюОбъекта(Источник) Тогда
        Возврат;
    КонецЕсли;
    ПродолжитьВызов(Источник, Отказ);
КонецПроцедуры

&Вместо("ОбменЗарплата3Бухгалтерия3ПередЗаписью")
Процедура Откл_ОбменЗарплата3Бухгалтерия3ПередЗаписью(Источник, Отказ)
    Если Откл_ПропуститьРегистрациюОбъекта(Источник) Тогда
        Возврат;
    КонецЕсли;
    ПродолжитьВызов(Источник, Отказ);
КонецПроцедуры

Функция Откл_ПропуститьРегистрациюОбъекта(Источник)
    
    сзИсточникМетаданныеИмя = Новый СписокЗначений;
    сзИсточникМетаданныеИмя.Добавить("ФизическиеЛица");    
    //...
    
    Если сзИсточникМетаданныеИмя.НайтиПоЗначению(Источник.Метаданные().Имя) <> Неопределено Тогда
        Возврат Истина;
    КонецЕсли;    
    
    Возврат Ложь;
    
КонецФункции

(2) + общий модуль в расширении БП "ОбменДаннымиСобытияБП". В других конфах другой подобный общий модуль.

типовое обновление правил не ломает эти блоки.